98e4b2882f
This PR migrates usages of `Std.Range` to the new polymorphic ranges. This PR unfortunately increases the transitive imports for frequently-used parts of `Init` because the ranges now rely on iterators in order to provide their functionality for types other than `Nat`. However, iteration over ranges in compiled code is as efficient as before in the examples I checked. This is because of a special `IteratorLoop` implementation provided in the PR for this purpose. There were two issues that were uncovered during migration: * In `IndPredBelow.lean`, migrating the last remaining range causes `compilerTest1.lean` to break. I have minimized the issue and came to the conclusion it's a compiler bug. Therefore, I have not replaced said old range usage yet (see #9186). * In `BRecOn.lean`, we are publicly importing the ranges. Making this import private should theoretically work, but there seems to be a problem with the module system, causing the build to panic later in `Init.Data.Grind.Poly` (see #9185). * In `FuzzyMatching.lean`, inlining fails with the new ranges, which would have led to significant slowdown. Therefore, I have not migrated this file either.
66 lines
1.9 KiB
Text
66 lines
1.9 KiB
Text
/-
|
||
Copyright (c) 2022 Microsoft Corporation. All rights reserved.
|
||
Released under Apache 2.0 license as described in the file LICENSE.
|
||
Authors: Leonardo de Moura
|
||
-/
|
||
prelude
|
||
import Lean.Compiler.LCNF.Simp.SimpM
|
||
|
||
namespace Lean.Compiler.LCNF
|
||
namespace Simp
|
||
|
||
/--
|
||
Return the alternative in `alts` whose body appears in most arms,
|
||
and the number of occurrences.
|
||
We use this function to decide whether to create a `.default` case
|
||
or not.
|
||
-/
|
||
private def getMaxOccs (alts : Array Alt) : Alt × Nat := Id.run do
|
||
let mut maxAlt := alts[0]!
|
||
let mut max := getNumOccsOf alts 0
|
||
for h : i in 1...alts.size do
|
||
let curr := getNumOccsOf alts i
|
||
if curr > max then
|
||
maxAlt := alts[i]
|
||
max := curr
|
||
return (maxAlt, max)
|
||
where
|
||
/--
|
||
Return the number of occurrences of `alts[i]` in `alts`.
|
||
We use alpha equivalence.
|
||
Note that the number of occurrences can be greater than 1 only when
|
||
the alternative does not depend on field parameters
|
||
-/
|
||
getNumOccsOf (alts : Array Alt) (i : Nat) : Nat := Id.run do
|
||
let code := alts[i]!.getCode
|
||
let mut n := 1
|
||
for h : j in (i+1)...alts.size do
|
||
if Code.alphaEqv alts[j].getCode code then
|
||
n := n+1
|
||
return n
|
||
|
||
/--
|
||
Add a default case to the given `cases` alternatives if there
|
||
are alternatives with equivalent (aka alpha equivalent) right hand sides.
|
||
-/
|
||
def addDefaultAlt (alts : Array Alt) : SimpM (Array Alt) := do
|
||
if alts.size <= 1 || alts.any (· matches .default ..) then
|
||
return alts
|
||
else
|
||
let (max, noccs) := getMaxOccs alts
|
||
if noccs == 1 then
|
||
return alts
|
||
else
|
||
let mut altsNew := #[]
|
||
let mut first := true
|
||
markSimplified
|
||
for alt in alts do
|
||
if Code.alphaEqv alt.getCode max.getCode then
|
||
let .alt _ ps k := alt | unreachable!
|
||
eraseParams ps
|
||
unless first do
|
||
eraseCode k
|
||
first := false
|
||
else
|
||
altsNew := altsNew.push alt
|
||
return altsNew.push (.default max.getCode)
|