3a457e6ad6
Many of our tests in `tests/lean/run/` produce output from `#eval` (or `#check`) statements, that is then ignored. This PR tries to capture all the useful output using `#guard_msgs`. I've only done a cursory check that the output is still sane --- there is a chance that some "unchecked" tests have already accumulated regressions and this just cements them! In the other direction, I did identify two rotten tests: * a minor one in `setStructInstNotation.lean`, where a comment says `Set Nat`, but `#check` actually prints `?_`. Weird? * `CompilerProbe.lean` is generating empty output, apparently indicating that something is broken, but I don't know the signficance of this file. In any case, I'll ask about these elsewhere. (This started by noticing that a recent `grind` test file had an untested `trace_state`, and then got carried away.)
70 lines
1.3 KiB
Text
70 lines
1.3 KiB
Text
import Lean
|
|
open Lean
|
|
open Lean.Elab
|
|
open Lean.Meta
|
|
open Lean.Elab.Tactic
|
|
|
|
/--
|
|
info: a b c : Nat
|
|
h₁ : a = b
|
|
h₂ : b = c
|
|
⊢ a = b
|
|
-/
|
|
#guard_msgs in
|
|
example (a b c : Nat) (h₁ : a = b) (h₂ : b = c) : a = c := by
|
|
apply Eq.trans _ h₂ -- the metavars created during elaboration become new goals
|
|
trace_state
|
|
exact h₁
|
|
|
|
/--
|
|
info: case h
|
|
a : Nat
|
|
⊢ ?w = a
|
|
|
|
case w
|
|
a : Nat
|
|
⊢ Nat
|
|
-/
|
|
#guard_msgs in
|
|
example (a : Nat) : ∃ x, x = a := by
|
|
apply Exists.intro -- the goal for the witness should occur "after" the goal for x = a
|
|
trace_state
|
|
rfl
|
|
|
|
elab "fapply " e:term : tactic =>
|
|
evalApplyLikeTactic (MVarId.apply (cfg := {newGoals := ApplyNewGoals.all})) e
|
|
|
|
elab "eapply " e:term : tactic =>
|
|
evalApplyLikeTactic (MVarId.apply (cfg := {newGoals := ApplyNewGoals.nonDependentOnly})) e
|
|
|
|
/--
|
|
info: case h
|
|
a : Nat
|
|
⊢ ?w = a
|
|
-/
|
|
#guard_msgs in
|
|
example (a : Nat) : ∃ x, x = a := by
|
|
eapply Exists.intro -- only metavars with out forward dependencies are added as goals.
|
|
trace_state
|
|
rfl
|
|
|
|
/--
|
|
info: case w
|
|
a : Nat
|
|
⊢ Nat
|
|
|
|
case h
|
|
a : Nat
|
|
⊢ ?w = a
|
|
---
|
|
info: case h
|
|
a : Nat
|
|
⊢ a = a
|
|
-/
|
|
#guard_msgs in
|
|
example (a : Nat) : ∃ x, x = a := by
|
|
fapply Exists.intro -- all unassigned metavars are added as new goals using the order they were created.
|
|
trace_state
|
|
exact a
|
|
trace_state
|
|
rfl
|